vlookup怎么用详细步骤（vlookup函数十大用法详解）

说的vlookup函数相信绝大多数同学都不陌生，在 Excel 中 vlookup 可以说是函数中的 NO.1，因为在日常数据查询过程过程中，这个函数的用法确实是非常的普遍。今天我们就来学习一下，vlookup 函数在各种数据场景下的全部十种用法。

案例说明：我们需要在左边人员信息数据中，通过人员的姓名向右查询对应人员的工号。

函数公式：

=VLOOKUP(G5,$B$2:$D$11,2,0)

函数解析：

1.1 vlookup 函数根据查询的条件值，向右查询我们需要的数据，这种用法是 vlookup 函数最为常见的一种用法；

1.2 vlookup 第一参数为查询的条件值，第二参数为需要查询取值的数据区域，第三参数代表从对应条件值所在列开始往右第几列，第四参数 0 代表精确查询（总共为 0 和 1 两个值，1 代表模糊查询。）

案例说明：数据向左查询是一种特别的查询方式，通过工号向左查询对应人员姓名，vlookup 函数也能实现。

函数公式：

=VLOOKUP(G5,IF({1,0},$C$2:$C$11,$B$2:$B$11),2,0)

函数解析：

1.1 vlookup 函数向左查询是一种特殊的用法，它需要搭配 IF 函数进行嵌套使用才能实现起功能；

1.2 向左查询需要用到 IF 函数来进行二次判断。参数 IF({1,0},$C$2:$C$11,$B$2:$B$11)，1 代表条件成立 C 列能查到工号时，查询的区域从$C$2:$C$11 到$B$2:$B$11，0 代表条件不成立也就是 C 列查找不到工号时候，查询的区域从$B$2:$B$11 到$C$2:$C$11。

案例说明：在这里我们需要通过对应人员姓名，批量的查询人员多个月份的数据，这里就涉及到数据的批量查询。

函数公式：

=VLOOKUP($B10,$A$1:$H$6,COLUMN(C10)+3,0)

函数解析：第一参数还是需要查询的人张三，注意 B10 单元格需要把列固定；第二参数函数对应区域不变；第三参数运用 column 返回当前列的方式自动变化，因为当前单元格为 C10 返回值为 3，而 4 月数据为从左往右第 6 列，所以需要再加 3。

案例说明：数据批量查询 vlookup 与 Column 函数，与 Match 函数进行嵌套运用同样可以实现数据的精确批量查找。如何实现根据姓名查询多月数据。

函数公式：

=VLOOKUP($B10,$A$1:$H$6,MATCH(C$9,$A$1:$H$1,0),0)

函数解析：同 colunm 函数类似，主要变更第三参数。第三参数 MATCH(C$9,$A$1:$H$1,0)=6，代表求出 4 月、5 月、6 月月份在标题行中所在的位置。

案例说明：vookup 函数在使用时，经常会碰到查询出错的情况，如数据源中没有这个人数据时，会出现错误值。为规避错误值我们就会用 iferror 函数来去除。

函数公式：

=IFERROR(VLOOKUP(C9,$B$1:$G$6,6,0),””)

函数解析：IFEEROR 函数为错误值处理函数，当出现错误值时可以用其他内容代替。函数参数为 IFERROR（有错误值，执行下一步）。没有错误值时正常显示。

案例说明：进行工资条的制作时，vlookup 函数同样可以很快的进行实现，主要也就是用了 vlookup 函数的查询功能。

函数公式：

=VLOOKUP($G96,$A$96:$E$104,COLUMN(B1),)

函数解析：根据数据源做工资条，主要的技巧有 2 个：1、我们往下拖动数据的时候，需要选中一行空白的单元格行，然后再往下移动即可；2、工资条前方提前输入数字 1，这样往下拖动可以自动更换，然后在数据源中做辅助列 1、2、3….，通过数字进行匹配查找。

案例说明：在我们的条件值可能包含很多内容的时候，我们如何根据一个字段中的一个字去查询数据，这就是需要用到通配符进行查询。

函数公式：

=VLOOKUP(“*”&F41&”*”,$B$41:$D$47,3,0)

函数解析：*代表任意字符，运用&符号进行连接代表镇流器三个字前可以是任意内容。

案例说明：vlookup 函数除了可以实现数据的单个条件查找，它还可以实现数据的多条件查询。如求出日期和单号两个条件下的仓库入库数量

函数公式：

{=VLOOKUP(G2&H2,IF({1,0},A:A&B:B,C:C),2,0)}

函数解析：关键点在于查找的条件值需要用&符号将两个条件连接成一个条件，同时第二参数运用 IF 判断函数同样的用&符号将查询区域进行连接。最后用 CTRL+SHIFT+ENTER 三键数值的方式进行计算。

案例说明：我们需要通过 vlookup 函数求出对人员 1-6 月数据后，将多个月数据进行一次性求和操作。这里就需要用到 sum 函数搭配使用。

函数公式：

=SUM(VLOOKUP(B11,$A$2:$G$8,{2,3,4,5,6,7},0))

函数解析：vlookup 函数求和重点有 2 个。1、第三参数查找的数据区域我们需要将每个月对应的列用{}数值的方式进行全部查找；2、当查找出来数据之后，最后用 sum 函数进行求和，最后用 CTRL+SHIFT+ENTER 三键数值的方式进行计算。

案例说明：我们都知道 vlookup 函数是只能查询单个数据，但实际它结合其他函数嵌套运用，也能实现数据的一对多查询，如通过姓名查找出当天的所有门禁刷卡数据

函数公式：

=IFERROR(VLOOKUP(ROW(A1),A:D,4,0),””)

函数解析：重点在于需要在数据源中做一列辅助列，函数为 COUNTIF(B$2:B2,G$2)，作为辅助列后通过 vlookup 函数查找对应的行数进行数据查找，往下拖动的时候就可以匹配出所有的数据。IFERROR 函数的用途在于当所有数据已经查找完，往下拖动出现错误值时用空格代替。

通过上对 vlookup 函数的全方位讲解，我们可以快速完成日常 Excel 数据处理中绝大多数的工作量，现在你学会了吗？

本文地址：网络知识频道 https://www.hkm168.com/jiqiao/1078363.html，易企推百科一个免费的知识分享平台，本站部分文章来网络分享，本着互联网分享的精神，如有涉及到您的权益，请联系我们删除，谢谢！